PS2Recomp/android/app/build.gradle

plugins {
    id 'com.android.application'
}

// Override with: gradlew assembleRelease -Pps2xBootElf=/absolute/path/on/device.elf
def ps2xBootElf = project.findProperty('ps2xBootElf') ?: '/storage/emulated/0/Android/data/com.ps2x.runner/files/game.elf'

android {
    namespace 'com.ps2x.runner'
    compileSdk 34
    ndkVersion '28.2.13676358'

    defaultConfig {
        applicationId 'com.ps2x.runner'
        minSdk 28
        targetSdk 34
        versionCode 1
        versionName '0.1.0'

        externalNativeBuild {
            cmake {
                arguments '-DPS2X_BUILD_RECOMP=OFF',
                        '-DPS2X_BUILD_ANALYZER=OFF',
                        '-DPS2X_BUILD_TEST=OFF',
                        '-DPS2X_BUILD_STUDIO=OFF',
                        '-DPS2X_ENABLE_SCCACHE=OFF',
                        '-DPS2X_RUNNER_UNITY_BUILD_BATCH_SIZE=32',
                        '-DANDROID_CPP_FEATURES=rtti exceptions',
                        "-DPS2X_DEFAULT_BOOT_ELF=${ps2xBootElf}"
                targets 'ps2EntryRunner'
            }
        }

        ndk {
            abiFilters 'arm64-v8a', 'x86_64'
        }
    }

    externalNativeBuild {
        cmake {
            path '../../CMakeLists.txt'
            version '3.22.1'
        }
    }

    buildTypes {
        debug {
            externalNativeBuild {
                cmake {
                    arguments '-DCMAKE_BUILD_TYPE=RelWithDebInfo'
                }
            }
        }
        release {
            minifyEnabled false
            signingConfig signingConfigs.debug
        }
    }
}