mirror of
https://github.com/ran-j/PS2Recomp.git
synced 2026-09-28 17:39:16 -04:00
Ranieri
8c8a97af65
* feat: added ffmepg as dependency * feat: wip decoder video * feat: some perf and cleanup * feat: added generic MPEG stream notification * feat: CMakeLists.txt in ps2xStudio to configure SDL2 build options for static linking. fix: fix ffmpeg setup for linux fix: now MPEG decoder now identify that movie has ended and can play again anytime feat: better audio stub to not block games * feat: fix expansion test * feat: foo * a * feat: finally added a helper to to prevent thread starvation * feat: added basic vu0 code execution * feat: added yield Guest Execution After Wake to prevent deadlock * feat: added options on cmake for logs feat: better input for keyboard pad * feat: small corrections like top and itop vu branches etc * feat: changes * feat: working feature * feat: fatal frame iop * feat: test fix feat: z buffer fix * fix: gix GsPutIMR IMR * feat: added rl imgui * feat: added helper to get snapshot * feat: added debug panel consuming snapshots * feat: added pad snapshot feat: added RCP debug events * feat: final cleanup from old code * feat: added EE timer counter feat: applyed sound driver for Lotr feat: better check for sound driver compat layout feat: enquee and cosumed DMa cause feat: added Pad execCMd feat: update GS vsync signal flag feat: custom IOPs for LotR * feat: small cleanups * fix: fix wrong import
93 lines
2.9 KiB
CMake
93 lines
2.9 KiB
CMake
cmake_minimum_required(VERSION 3.21)
|
|
|
|
if(NOT DEFINED CMAKE_TOOLCHAIN_FILE AND DEFINED ENV{VITASDK})
|
|
set(PS2X_VITA_TOOLCHAIN_FILE "$ENV{VITASDK}/share/vita.toolchain.cmake")
|
|
if(EXISTS "${PS2X_VITA_TOOLCHAIN_FILE}")
|
|
set(CMAKE_TOOLCHAIN_FILE "${PS2X_VITA_TOOLCHAIN_FILE}" CACHE PATH
|
|
"Toolchain file used for cross-compiling" FORCE)
|
|
message(STATUS "Using VitaSDK toolchain from VITASDK: ${CMAKE_TOOLCHAIN_FILE}")
|
|
endif()
|
|
endif()
|
|
|
|
project(PS2RetroX)
|
|
|
|
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
|
|
|
|
option(PS2X_BUILD_RECOMP "Build ps2xRecomp" ON)
|
|
option(PS2X_BUILD_RUNTIME "Build ps2xRuntime" ON)
|
|
option(PS2X_BUILD_ANALYZER "Build ps2xAnalyzer" ON)
|
|
option(PS2X_BUILD_TEST "Build ps2xTest" ON)
|
|
option(PS2X_BUILD_STUDIO "Build ps2xStudio" ON)
|
|
|
|
set(PS2X_IS_ARM_TARGET OFF)
|
|
set(PS2X_IS_AARCH64_TARGET OFF)
|
|
if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm64|aarch64|ARM64")
|
|
set(PS2X_IS_ARM_TARGET ON)
|
|
set(PS2X_IS_AARCH64_TARGET ON)
|
|
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^arm|^ARM")
|
|
set(PS2X_IS_ARM_TARGET ON)
|
|
endif()
|
|
|
|
if((CMAKE_C_COMPILER MATCHES "arm-vita-eabi") OR
|
|
(CMAKE_CXX_COMPILER MATCHES "arm-vita-eabi"))
|
|
set(PS2X_IS_ARM_TARGET ON)
|
|
endif()
|
|
|
|
if(PS2X_IS_ARM_TARGET)
|
|
message(STATUS "ARM target detected, fetching sse2neon")
|
|
|
|
include(FetchContent)
|
|
FetchContent_Declare(
|
|
sse2neon
|
|
GIT_REPOSITORY https://github.com/DLTcollab/sse2neon.git
|
|
GIT_TAG v1.9.1
|
|
GIT_SHALLOW TRUE
|
|
)
|
|
FetchContent_MakeAvailable(sse2neon)
|
|
|
|
include_directories(${sse2neon_SOURCE_DIR})
|
|
add_compile_definitions(USE_SSE2NEON)
|
|
|
|
if(PS2X_IS_AARCH64_TARGET AND APPLE)
|
|
# macOS ARM64 already uses optimal defaults
|
|
message(STATUS "macOS ARM64 - using default compiler flags")
|
|
elseif(PS2X_IS_AARCH64_TARGET AND MSVC)
|
|
# Windows ARM64 - MSVC already uses optimal defaults
|
|
message(STATUS "Windows ARM64 (MSVC) - using default compiler flags")
|
|
elseif(PS2X_IS_AARCH64_TARGET)
|
|
# Linux ARM64 - add NEON flags
|
|
message(STATUS "Non-Apple ARM64 - adding NEON compiler flags")
|
|
add_compile_options(-march=armv8-a+fp+simd)
|
|
|
|
# Try to enable crypto and CRC extensions if supported
|
|
include(CheckCXXCompilerFlag)
|
|
check_cxx_compiler_flag("-march=armv8-a+fp+simd+crypto+crc" COMPILER_SUPPORTS_CRYPTO_CRC)
|
|
if(COMPILER_SUPPORTS_CRYPTO_CRC)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -march=armv8-a+fp+simd+crypto+crc")
|
|
message(STATUS "Crypto and CRC extensions enabled")
|
|
else()
|
|
add_compile_options(-march=armv8-a+fp+simd)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(PS2X_BUILD_RECOMP)
|
|
add_subdirectory("ps2xRecomp")
|
|
endif()
|
|
|
|
if(PS2X_BUILD_RUNTIME)
|
|
add_subdirectory("ps2xRuntime")
|
|
endif()
|
|
|
|
if(PS2X_BUILD_ANALYZER)
|
|
add_subdirectory("ps2xAnalyzer")
|
|
endif()
|
|
|
|
if(PS2X_BUILD_TEST)
|
|
add_subdirectory("ps2xTest")
|
|
endif()
|
|
|
|
if(PS2X_BUILD_STUDIO)
|
|
add_subdirectory("ps2xStudio")
|
|
endif()
|