mirror of
https://github.com/HarbourMasters/SpaghettiKart
synced 2026-08-23 07:29:37 -04:00
coco875
4c24ae2bc2
* some start of refactor * Update SetFlags.cmake * Update SetCmakeVar.cmake * Update SetFlags.cmake * Fix error int-convertion * more refactor * clean up include and source file * fix link of lib * fix a warning * fix include in src/actors * fix include in src/debug * fix include in src/ending * fix include in src/engine/actors * fix include in src/engine/cameras * fix include in src/engine/editor * fix include in src/engine/objects * fix include in src/engine/tracks * fix include in src/port/ui * fix include in src/racing * fix include in src/engine/vehicles * fix include in subfolder of src/engine * fix include in src/engine * fix include in src/enhancements * fix include in src * fix switch * invert common and findlib * Update SetFlags.cmake * clean up some workflow * some splification * Update build.sh * Update Game.h * add header back * Delete test_check.cmake * continue * Update common.cmake
96 lines
3.9 KiB
CMake
96 lines
3.9 KiB
CMake
# these are cache variables, so they could be overwritten with -D,
|
|
|
|
set(CPACK_PACKAGE_NAME "${PROJECT_NAME}"
|
|
CACHE STRING "The resulting package name"
|
|
)
|
|
|
|
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simple C++ application"
|
|
CACHE STRING "Package description for the package metadata"
|
|
)
|
|
set(CPACK_PACKAGE_VENDOR "Some Company")
|
|
|
|
set(CPACK_VERBATIM_VARIABLES YES)
|
|
|
|
set(CPACK_PACKAGE_INSTALL_DIRECTORY ${CPACK_PACKAGE_NAME})
|
|
SET(CPACK_OUTPUT_FILE_PREFIX "${CMAKE_SOURCE_DIR}/_packages")
|
|
|
|
set(CPACK_PACKAGE_VERSION_MAJOR ${PROJECT_VERSION_MAJOR})
|
|
set(CPACK_PACKAGE_VERSION_MINOR ${PROJECT_VERSION_MINOR})
|
|
set(CPACK_PACKAGE_VERSION_PATCH ${PROJECT_VERSION_PATCH})
|
|
set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
|
|
|
|
set(CPACK_PACKAGE_CONTACT "YOUR@E-MAIL.net")
|
|
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "YOUR NAME")
|
|
|
|
# set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.md")
|
|
set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/README.md")
|
|
|
|
if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
|
|
set(CPACK_SYSTEM_NAME ${LSB_RELEASE_CODENAME_SHORT})
|
|
# package name for deb
|
|
# if set, then instead of some-application-0.9.2-Linux.deb
|
|
# you'll get some-application_0.9.2_amd64.deb (note the underscores too)
|
|
#set(CPACK_DEBIAN_FILE_NAME DEB-DEFAULT)
|
|
execute_process(COMMAND dpkg --print-architecture OUTPUT_VARIABLE ARCHITECTURE OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
set( CPACK_DEBIAN_FILE_NAME ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}-${ARCHITECTURE}.deb )
|
|
# if you want every group to have its own package,
|
|
# although the same happens if this is not sent (so it defaults to ONE_PER_GROUP)
|
|
# and CPACK_DEB_COMPONENT_INSTALL is set to YES
|
|
set(CPACK_COMPONENTS_GROUPING ALL_COMPONENTS_IN_ONE)#ONE_PER_GROUP)
|
|
# without this you won't be able to pack only specified component
|
|
set(CPACK_DEB_COMPONENT_INSTALL YES)
|
|
|
|
set(CPACK_EXTERNAL_ENABLE_STAGING YES)
|
|
set(CPACK_EXTERNAL_PACKAGE_SCRIPT "${PROJECT_BINARY_DIR}/appimage-generate.cmake")
|
|
|
|
set(APPIMAGE_SCRIPT_TEMPLATE [[
|
|
include(CMakePrintHelpers)
|
|
cmake_print_variables(CPACK_TEMPORARY_DIRECTORY)
|
|
cmake_print_variables(CPACK_TOPLEVEL_DIRECTORY)
|
|
cmake_print_variables(CPACK_PACKAGE_DIRECTORY)
|
|
cmake_print_variables(CPACK_PACKAGE_FILE_NAME)
|
|
|
|
find_program(LINUXDEPLOY_EXECUTABLE
|
|
NAMES linuxdeploy linuxdeploy-x86_64.AppImage
|
|
PATHS ${CPACK_PACKAGE_DIRECTORY}/linuxdeploy)
|
|
|
|
if (NOT LINUXDEPLOY_EXECUTABLE)
|
|
message(STATUS "Downloading linuxdeploy")
|
|
set(LINUXDEPLOY_EXECUTABLE ${CPACK_PACKAGE_DIRECTORY}/linuxdeploy/linuxdeploy)
|
|
file(DOWNLOAD
|
|
https://github.com/linuxdeploy/linuxdeploy/releases/download/1-alpha-20251107-1/linuxdeploy-x86_64.AppImage
|
|
${LINUXDEPLOY_EXECUTABLE}
|
|
INACTIVITY_TIMEOUT 10
|
|
LOG ${CPACK_PACKAGE_DIRECTORY}/linuxdeploy/download.log
|
|
STATUS LINUXDEPLOY_DOWNLOAD)
|
|
execute_process(COMMAND chmod +x ${LINUXDEPLOY_EXECUTABLE} COMMAND_ECHO STDOUT)
|
|
endif()
|
|
|
|
execute_process(
|
|
COMMAND ${CMAKE_COMMAND}
|
|
-DSOURCE_DIR=${CPACK_PACKAGE_DIRECTORY}
|
|
-DDESTINATION_DIR=${CPACK_TEMPORARY_DIRECTORY}/usr/bin
|
|
-P @CMAKE_CURRENT_LIST_DIR@/StageRuntimeFiles.cmake
|
|
COMMAND
|
|
${CMAKE_COMMAND} -E env
|
|
OUTPUT=${CPACK_PACKAGE_FILE_NAME}.appimage
|
|
VERSION=$<IF:$<BOOL:${CPACK_PACKAGE_VERSION}>,${CPACK_PACKAGE_VERSION},0.1.0>
|
|
NO_STRIP=true
|
|
${LINUXDEPLOY_EXECUTABLE}
|
|
--appimage-extract-and-run
|
|
--appdir=${CPACK_TEMPORARY_DIRECTORY}
|
|
--executable=$<TARGET_FILE:@PROJECT_NAME@>
|
|
$<$<BOOL:$<TARGET_PROPERTY:@PROJECT_NAME@,APPIMAGE_DESKTOP_FILE>>:--desktop-file=$<TARGET_PROPERTY:@PROJECT_NAME@,APPIMAGE_DESKTOP_FILE>>
|
|
$<$<BOOL:$<TARGET_PROPERTY:@PROJECT_NAME@,APPIMAGE_ICON_FILE>>:--icon-file=$<TARGET_PROPERTY:@PROJECT_NAME@,APPIMAGE_ICON_FILE>>
|
|
--output=appimage
|
|
--verbosity=2
|
|
)
|
|
]])
|
|
string(CONFIGURE "${APPIMAGE_SCRIPT_TEMPLATE}" APPIMAGE_SCRIPT @ONLY)
|
|
file(GENERATE OUTPUT "${PROJECT_BINARY_DIR}/appimage-generate.cmake"
|
|
CONTENT "${APPIMAGE_SCRIPT}")
|
|
|
|
endif()
|
|
|
|
include(CPack)
|