mirror of
https://github.com/open-goal/jak-project
synced 2026-06-04 18:59:37 -04:00
Tyler Wilding
1f6438e517
This PR updates to SDL3, and with it, adds a handful of new features. Everything seems to work but I'm going to look over the code once last time before merging, some of the API changes are hard to spot. Fixes #2773 ### Pressure sensitivity support for DS3 Controllers SDL3 adds pressure sensitivity support for DS3 controllers on windows. I have not tested on linux. The option is disabled by default. On windows you will need https://docs.nefarius.at/projects/DsHidMini/ and to be using SXS mode. ### DualSense and Xbox One Trigger Effects If enabled, Jak 2 will have certain trigger effects. They are: - xbox1: - small vibrate when collecting dark eco - big vibrate when changing to dark jak - vibrate when shooting gun, proportional to gun type - ps5: - resistance when changing to dark jak - different gun shooting effects - red (resistance) - yellow (weapon trigger) - blue (vibrates) - purple (less resistance) > **Gun Shooting effects are only enabled if the new "Swap R1 and R2" option is enabled** There are more effects that could be used in `dualsense_effects.cpp`, but I only exposed the ones I needed to OpenGOAL. If a modder wants to use some of the others and wires them up end-to-end, please consider contributing that upstream. ### New ImGUI Menu Added new imgui options for selecting the active controller, for those people that struggle to select the initial controller.  ### Testing The highlights of what I tested successfully: - display - [x] all mode switch permutations - [x] launch with all modes saved - [x] switch monitors / unplug monitor that was active, how does it handle it - [x] load with alternate monitor saved and all modes - [x] allowing hidpi doesnt break macos - controls - [x] keyboard and mouse still work - [x] pressure sensitivity on linux
125 lines
3.7 KiB
CMake
Vendored
Generated
125 lines
3.7 KiB
CMake
Vendored
Generated
#[=======================================================================[
|
|
|
|
FindSdlAndroidPlatform
|
|
----------------------
|
|
|
|
Locate the Android SDK platform.
|
|
|
|
|
|
Imported targets
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This module defines the following :prop_tgt:`IMPORTED` target(s):
|
|
|
|
<none>
|
|
|
|
Result variables
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This find module will set the following variables in your project:
|
|
|
|
`` SdlAndroidPlatform_FOUND
|
|
if false, no Android platform has been found
|
|
|
|
`` SDL_ANDROID_PLATFORM_ROOT
|
|
path of the Android SDK platform root directory if found
|
|
|
|
`` SDL_ANDROID_PLATFORM_ANDROID_JAR
|
|
path of the Android SDK platform jar file if found
|
|
|
|
`` SDL_ANDROID_PLATFORM_VERSION
|
|
the human-readable string containing the android platform version if found
|
|
|
|
Cache variables
|
|
^^^^^^^^^^^^^^^
|
|
|
|
These variables may optionally be set to help this module find the correct files:
|
|
|
|
``SDL_ANDROID_PLATFORM_ROOT``
|
|
path of the Android SDK platform root directory
|
|
|
|
|
|
Variables for locating Android platform
|
|
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
|
|
|
|
This module responds to the flags:
|
|
|
|
``SDL_ANDROID_HOME
|
|
First, this module will look for platforms in this CMake variable.
|
|
|
|
``ANDROID_HOME
|
|
If no platform was found in `SDL_ANDROID_HOME`, then try `ANDROID_HOME`.
|
|
|
|
``$ENV{ANDROID_HOME}
|
|
If no platform was found in neither `SDL_ANDROID_HOME` or `ANDROID_HOME`, then try `ANDROID_HOME}`
|
|
|
|
#]=======================================================================]
|
|
|
|
cmake_minimum_required(VERSION 3.7...3.28)
|
|
|
|
if(NOT PROJECT_NAME MATCHES "^SDL.*")
|
|
message(WARNING "This module is internal to SDL and is currently not supported.")
|
|
endif()
|
|
|
|
function(_sdl_is_valid_android_platform_root RESULT VERSION PLATFORM_ROOT)
|
|
set(result FALSE)
|
|
set(version -1)
|
|
|
|
string(REGEX MATCH "/android-([0-9]+)$" root_match "${PLATFORM_ROOT}")
|
|
if(root_match AND EXISTS "${PLATFORM_ROOT}/android.jar")
|
|
set(result TRUE)
|
|
set(version "${CMAKE_MATCH_1}")
|
|
endif()
|
|
|
|
set(${RESULT} ${result} PARENT_SCOPE)
|
|
set(${VERSION} ${version} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(_sdl_find_android_platform_root ROOT)
|
|
cmake_parse_arguments(sfapr "" "" "" ${ARGN})
|
|
set(homes ${SDL_ANDROID_HOME} ${ANDROID_HOME} $ENV{ANDROID_HOME})
|
|
set(root ${ROOT}-NOTFOUND)
|
|
foreach(home IN LISTS homes)
|
|
if(NOT IS_DIRECTORY "${home}")
|
|
continue()
|
|
endif()
|
|
file(GLOB platform_roots LIST_DIRECTORIES true "${home}/platforms/*")
|
|
set(max_platform_version -1)
|
|
set(max_platform_root "")
|
|
foreach(platform_root IN LISTS platform_roots)
|
|
_sdl_is_valid_android_platform_root(is_valid platform_version "${platform_root}")
|
|
if(is_valid AND platform_version GREATER max_platform_version)
|
|
set(max_platform_version "${platform_version}")
|
|
set(max_platform_root "${platform_root}")
|
|
endif()
|
|
endforeach()
|
|
if(max_platform_version GREATER -1)
|
|
set(root ${max_platform_root})
|
|
break()
|
|
endif()
|
|
endforeach()
|
|
set(${ROOT} ${root} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
set(SDL_ANDROID_PLATFORM_ANDROID_JAR "SDL_ANDROID_PLATFORM_ANDROID_JAR-NOTFOUND")
|
|
|
|
if(NOT DEFINED SDL_ANDROID_PLATFORM_ROOT)
|
|
_sdl_find_android_platform_root(_new_sdl_android_platform_root)
|
|
set(SDL_ANDROID_PLATFORM_ROOT "${_new_sdl_android_platform_root}" CACHE PATH "Path of Android platform")
|
|
unset(_new_sdl_android_platform_root)
|
|
endif()
|
|
if(SDL_ANDROID_PLATFORM_ROOT)
|
|
_sdl_is_valid_android_platform_root(_valid SDL_ANDROID_PLATFORM_VERSION "${SDL_ANDROID_PLATFORM_ROOT}")
|
|
if(_valid)
|
|
set(SDL_ANDROID_PLATFORM_ANDROID_JAR "${SDL_ANDROID_PLATFORM_ROOT}/android.jar")
|
|
endif()
|
|
unset(_valid)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
find_package_handle_standard_args(SdlAndroidPlatform
|
|
VERSION_VAR SDL_ANDROID_PLATFORM_VERSION
|
|
REQUIRED_VARS SDL_ANDROID_PLATFORM_ROOT SDL_ANDROID_PLATFORM_ANDROID_JAR
|
|
)
|