mirror of
https://github.com/open-goal/jak-project
synced 2026-05-28 00:16:20 -04:00
Tyler Wilding
1f6438e517
This PR updates to SDL3, and with it, adds a handful of new features. Everything seems to work but I'm going to look over the code once last time before merging, some of the API changes are hard to spot. Fixes #2773 ### Pressure sensitivity support for DS3 Controllers SDL3 adds pressure sensitivity support for DS3 controllers on windows. I have not tested on linux. The option is disabled by default. On windows you will need https://docs.nefarius.at/projects/DsHidMini/ and to be using SXS mode. ### DualSense and Xbox One Trigger Effects If enabled, Jak 2 will have certain trigger effects. They are: - xbox1: - small vibrate when collecting dark eco - big vibrate when changing to dark jak - vibrate when shooting gun, proportional to gun type - ps5: - resistance when changing to dark jak - different gun shooting effects - red (resistance) - yellow (weapon trigger) - blue (vibrates) - purple (less resistance) > **Gun Shooting effects are only enabled if the new "Swap R1 and R2" option is enabled** There are more effects that could be used in `dualsense_effects.cpp`, but I only exposed the ones I needed to OpenGOAL. If a modder wants to use some of the others and wires them up end-to-end, please consider contributing that upstream. ### New ImGUI Menu Added new imgui options for selecting the active controller, for those people that struggle to select the initial controller.  ### Testing The highlights of what I tested successfully: - display - [x] all mode switch permutations - [x] launch with all modes saved - [x] switch monitors / unplug monitor that was active, how does it handle it - [x] load with alternate monitor saved and all modes - [x] allowing hidpi doesnt break macos - controls - [x] keyboard and mouse still work - [x] pressure sensitivity on linux
116 lines
3.5 KiB
CMake
Vendored
Generated
116 lines
3.5 KiB
CMake
Vendored
Generated
#[=======================================================================[
|
|
|
|
FindSdlAndroidBuildTools
|
|
----------------------
|
|
|
|
Locate the Android build tools directory.
|
|
|
|
|
|
Imported targets
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This find module defines the following :prop_tgt:`IMPORTED` target(s):
|
|
|
|
<none>
|
|
|
|
Result variables
|
|
^^^^^^^^^^^^^^^^
|
|
|
|
This module will set the following variables in your project:
|
|
|
|
`` SdlAndroidBuildTools_FOUND
|
|
if false, no Android build tools have been found
|
|
|
|
`` SDL_ANDROID_BUILD_TOOLS_ROOT
|
|
path of the Android build tools root directory if found
|
|
|
|
`` SDL_ANDROID_BUILD_TOOLS_VERSION
|
|
the human-readable string containing the android build tools version if found
|
|
|
|
Cache variables
|
|
^^^^^^^^^^^^^^^
|
|
|
|
These variables may optionally be set to help this module find the correct files:
|
|
|
|
``SDL_ANDROID_BUILD_TOOLS_ROOT``
|
|
path of the Android build tools root directory
|
|
|
|
|
|
Variables for locating Android platform
|
|
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
|
|
|
|
This module responds to the flags:
|
|
|
|
``SDL_ANDROID_HOME
|
|
First, this module will look for platforms in this CMake variable.
|
|
|
|
``ANDROID_HOME
|
|
If no platform was found in `SDL_ANDROID_HOME`, then try `ANDROID_HOME`.
|
|
|
|
``$ENV{ANDROID_HOME}
|
|
If no platform was found in neither `SDL_ANDROID_HOME` or `ANDROID_HOME`, then try `ANDROID_HOME}`
|
|
|
|
#]=======================================================================]
|
|
|
|
cmake_minimum_required(VERSION 3.7...3.28)
|
|
|
|
if(NOT PROJECT_NAME MATCHES "^SDL.*")
|
|
message(WARNING "This module is internal to SDL and is currently not supported.")
|
|
endif()
|
|
|
|
function(_sdl_is_valid_android_build_tools_root RESULT VERSION BUILD_TOOLS_ROOT)
|
|
set(result TRUE)
|
|
set(version -1)
|
|
|
|
string(REGEX MATCH "/([0-9.]+)$" root_match "${BUILD_TOOLS_ROOT}")
|
|
if(root_match
|
|
AND EXISTS "${BUILD_TOOLS_ROOT}/aapt2"
|
|
AND EXISTS "${BUILD_TOOLS_ROOT}/apksigner"
|
|
AND EXISTS "${BUILD_TOOLS_ROOT}/d8"
|
|
AND EXISTS "${BUILD_TOOLS_ROOT}/zipalign")
|
|
set(result "${BUILD_TOOLS_ROOT}")
|
|
set(version "${CMAKE_MATCH_1}")
|
|
endif()
|
|
|
|
set(${RESULT} ${result} PARENT_SCOPE)
|
|
set(${VERSION} ${version} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(_find_sdl_android_build_tools_root ROOT)
|
|
cmake_parse_arguments(fsabtr "" "" "" ${ARGN})
|
|
set(homes ${SDL_ANDROID_HOME} ${ANDROID_HOME} $ENV{ANDROID_HOME})
|
|
set(root ${ROOT}-NOTFOUND)
|
|
foreach(home IN LISTS homes)
|
|
if(NOT IS_DIRECTORY "${home}")
|
|
continue()
|
|
endif()
|
|
file(GLOB build_tools_roots LIST_DIRECTORIES true "${home}/build-tools/*")
|
|
set(max_build_tools_version -1)
|
|
set(max_build_tools_root "")
|
|
foreach(build_tools_root IN LISTS build_tools_roots)
|
|
_sdl_is_valid_android_build_tools_root(is_valid build_tools_version "${build_tools_root}")
|
|
if(is_valid AND build_tools_version GREATER max_build_tools_version)
|
|
set(max_build_tools_version "${build_tools_version}")
|
|
set(max_build_tools_root "${build_tools_root}")
|
|
endif()
|
|
endforeach()
|
|
if(max_build_tools_version GREATER -1)
|
|
set(root ${max_build_tools_root})
|
|
break()
|
|
endif()
|
|
endforeach()
|
|
set(${ROOT} ${root} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
if(NOT DEFINED SDL_ANDROID_BUILD_TOOLS_ROOT)
|
|
_find_sdl_android_build_tools_root(SDL_ANDROID_BUILD_TOOLS_ROOT)
|
|
set(SDL_ANDROID_BUILD_TOOLS_ROOT "${SDL_ANDROID_BUILD_TOOLS_ROOT}" CACHE PATH "Path of Android build tools")
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
find_package_handle_standard_args(SdlAndroidBuildTools
|
|
VERSION_VAR SDL_ANDROID_BUILD_TOOLS_VERSION
|
|
REQUIRED_VARS SDL_ANDROID_BUILD_TOOLS_ROOT
|
|
)
|