mirror of
https://github.com/open-goal/jak-project
synced 2026-08-27 00:23:50 -04:00
Alexander J. Semenuk
5d5e35fb9b
## Problem Windows builds break with a current local toolchain (Scoop LLVM 22.1.8, CMake 4.4.0, VS 2026), in two independent ways: 1. The build stops at curl's deliberate guard: `#error "no non-blocking method was found/used/set"` in `third-party/curl/lib/nonblock.c`. 2. From the second configure onward, `cmake --build` re-runs CMake in an endless loop (observed 42 consecutive reconfigure cycles in a single build). Likely the same mechanism behind the "endlessly building" VS 2026 note in `docs/setup/dev/vs.md`. ## Root cause 1. `third-party/curl/CMake/CurlTests.c` passes `int *` to `ioctlsocket()`, whose third parameter is `u_long *`. Clang 22 promotes `-Wincompatible-pointer-types` to a hard error in C, so the `HAVE_IOCTLSOCKET_FIONBIO` try_compile silently fails and `curl_config.h` never defines it. Upstream CI does not see this because the windows-2022 runner image ships an older LLVM. GCC 14 promotes the same warning to a hard error, which is very likely the `CurlTests.c.obj` failure reported from MSYS2 in open-goal/jak-project#3551. Upstream curl hit the identical problem with GCC 14 and fixed the probe in curl 8.8.0 (curl/curl#13578). 2. The root CMakeLists copies the build tree's `compile_commands.json` into `<src>/build/` for clangd using `configure_file()`, which registers its input as a configure dependency. CMake rewrites `compile_commands.json` late in every generation, after `CTestTestfile.cmake` and `cmake_install.cmake` (outputs of the same Ninja regen rule), so once the dependency is registered the rule is deterministically dirty and every `ninja` invocation re-runs CMake. A pristine first configure is safe (the file does not exist yet, so the `if(EXISTS ...)` guard skips the copy), which is why the loop looks machine- or IDE-specific. ## Fix 1. Per review, re-vendor `third-party/curl` at the `curl-8_21_0` tag (previously `curl-8_3_0`), which carries the upstream probe fix plus two years of upstream development; `vendor.yaml` updated to match. Adjustments the version jump forced: - curl 8.15 removed the native macOS Secure Transport backend (`CURL_USE_SECTRANSP`), so macOS now builds curl against OpenSSL like Linux. The two macOS workflows install Homebrew `openssl@3` and export `OPENSSL_ROOT_DIR` (keg-only), and the macOS setup docs gained the same two lines. - `CURL_BROTLI` / `CURL_ZSTD` switched to AUTO-detection in curl 8.10; pinned OFF to keep the previous no-compression behavior and avoid silently linking whatever the CI images happen to have. - curl's new top-level `BUILD_EXAMPLES` cache option (default ON) leaked into discord-rpc's identically named option and broke configure at a nonexistent `examples/send-presence` directory; pinned OFF ahead of the third-party subdirectories. The diff is dominated by the mechanical tag-tree swap under `third-party/curl` (linguist-vendored, collapsed in review). The hand-written changes are `CMakeLists.txt`, the two macOS workflows, `docs/setup/system/macos.md`, and `vendor.yaml`. 2. Swap `configure_file()` for `file(COPY ...)`: the same clangd copy with no configure dependency registered. (`file(COPY_FILE ... ONLY_IF_DIFFERENT)` would be cleaner still but requires CMake 3.21, above the declared `cmake_minimum_required(VERSION 3.10)`.) ## Test plan - [x] Fresh `cmake --preset Release-windows-clang` (LLVM 22, no cache seeding) completes and logs `Enabled SSL backends: Schannel`; the FIONBIO probe passes without the previous `#error` - [x] Full Windows Release build from scratch in the branch worktree (all 1422 targets) - [x] goalc-test suite: 1509 passed, 0 failed - [x] Second consecutive configure with `compile_commands.json` present: the regen rule in `build.ninja` has no `compile_commands.json` input; `<src>/build/compile_commands.json` is still refreshed for clangd - [x] Repeated `ninja` invocations after a full build no longer re-run CMake - [x] macOS Intel and ARM CI green (first exercise of the OpenSSL backend switch) --- I work off a self-hosted forge, so this GitHub account is quiet; the configure logs and ninja dirty-node traces from the investigation are available if anyone wants the raw data. (AI-assisted)
98 lines
3.5 KiB
CMake
Vendored
Generated
98 lines
3.5 KiB
CMake
Vendored
Generated
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the nettle library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `NETTLE_INCLUDE_DIR`: Absolute path to nettle include directory.
|
|
# - `NETTLE_LIBRARY`: Absolute path to `nettle` library.
|
|
#
|
|
# Defines:
|
|
#
|
|
# - `NETTLE_FOUND`: System has nettle.
|
|
# - `NETTLE_VERSION`: Version of nettle.
|
|
# - `CURL::nettle`: nettle library target.
|
|
|
|
set(_nettle_pc_requires "nettle")
|
|
|
|
if(CURL_USE_PKGCONFIG AND
|
|
NOT DEFINED NETTLE_INCLUDE_DIR AND
|
|
NOT DEFINED NETTLE_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_nettle ${_nettle_pc_requires})
|
|
endif()
|
|
|
|
if(_nettle_FOUND)
|
|
set(Nettle_FOUND TRUE)
|
|
set(NETTLE_FOUND TRUE)
|
|
set(NETTLE_VERSION ${_nettle_VERSION})
|
|
message(STATUS "Found Nettle (via pkg-config): ${_nettle_INCLUDE_DIRS} (found version \"${NETTLE_VERSION}\")")
|
|
else()
|
|
find_path(NETTLE_INCLUDE_DIR NAMES "nettle/sha2.h")
|
|
find_library(NETTLE_LIBRARY NAMES "nettle")
|
|
|
|
unset(NETTLE_VERSION CACHE)
|
|
if(NETTLE_INCLUDE_DIR AND EXISTS "${NETTLE_INCLUDE_DIR}/nettle/version.h")
|
|
set(_version_regex1 "#[\t ]*define[ \t]+NETTLE_VERSION_MAJOR[ \t]+([0-9]+).*")
|
|
set(_version_regex2 "#[\t ]*define[ \t]+NETTLE_VERSION_MINOR[ \t]+([0-9]+).*")
|
|
file(STRINGS "${NETTLE_INCLUDE_DIR}/nettle/version.h" _version_str1 REGEX "${_version_regex1}")
|
|
file(STRINGS "${NETTLE_INCLUDE_DIR}/nettle/version.h" _version_str2 REGEX "${_version_regex2}")
|
|
string(REGEX REPLACE "${_version_regex1}" "\\1" _version_str1 "${_version_str1}")
|
|
string(REGEX REPLACE "${_version_regex2}" "\\1" _version_str2 "${_version_str2}")
|
|
set(NETTLE_VERSION "${_version_str1}.${_version_str2}")
|
|
unset(_version_regex1)
|
|
unset(_version_regex2)
|
|
unset(_version_str1)
|
|
unset(_version_str2)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(Nettle
|
|
REQUIRED_VARS
|
|
NETTLE_INCLUDE_DIR
|
|
NETTLE_LIBRARY
|
|
VERSION_VAR
|
|
NETTLE_VERSION
|
|
)
|
|
|
|
if(NETTLE_FOUND)
|
|
set(_nettle_INCLUDE_DIRS ${NETTLE_INCLUDE_DIR})
|
|
set(_nettle_LIBRARIES ${NETTLE_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(NETTLE_INCLUDE_DIR NETTLE_LIBRARY)
|
|
endif()
|
|
|
|
if(NETTLE_FOUND)
|
|
if(NOT TARGET CURL::nettle)
|
|
add_library(CURL::nettle INTERFACE IMPORTED)
|
|
set_target_properties(CURL::nettle PROPERTIES
|
|
INTERFACE_LIBCURL_PC_MODULES "${_nettle_pc_requires}"
|
|
INTERFACE_COMPILE_OPTIONS "${_nettle_CFLAGS}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${_nettle_INCLUDE_DIRS}"
|
|
INTERFACE_LINK_DIRECTORIES "${_nettle_LIBRARY_DIRS}"
|
|
INTERFACE_LINK_LIBRARIES "${_nettle_LIBRARIES}")
|
|
endif()
|
|
endif()
|