mirror of
https://github.com/open-goal/jak-project
synced 2026-07-09 23:01:56 -04:00
ManDude
5b44aece75
* delete unused shaders * hide some options in debug menu * change fullscreen logic a bit * add "all actors" toggle * borderless fix and fix alpha in direct renderer untextured (do we need a separate shader for that?) * fix fuel cell orbit icons in widescreen * fix `curve` types * refs * fix levitator task... * fix some task stuff * update font code a bit (temp) * cmake, third-party and visual studio overhaul * Update .gitmodules * update modules * clone repos * fix encoding in zydis * where did these come from * try again * add submodule * Update 11zip * Update 11zip * Update 11zip * delete * try again * clang * update compiler flags * delete 11zip. go away. * Create memory-dump-p2s.py * properly * fix minimum architecture c++ compiler flags * fix zydis * oops * Update all-types.gc * fix clang-cl tests * make "all actors" work better, entity debug qol * update game-text conversion code to be more modularized * Create vendor.txt * fix typos and minor things * update refs * clang * Attempt to add clang-cl support to vs2019 and CI * vs2022 + clang-cl * srsly? fix clang build * Update launch.vs.json * extend windows CI timer
47 lines
1.4 KiB
CMake
Vendored
Generated
47 lines
1.4 KiB
CMake
Vendored
Generated
|
|
# NOTE: The order of this list determines the order of items in the Guides
|
|
# (i.e. Pages) list in the generated documentation
|
|
set(source_files
|
|
main.dox
|
|
news.dox
|
|
quick.dox
|
|
moving.dox
|
|
compile.dox
|
|
build.dox
|
|
intro.dox
|
|
context.dox
|
|
monitor.dox
|
|
window.dox
|
|
input.dox
|
|
vulkan.dox
|
|
compat.dox
|
|
internal.dox)
|
|
|
|
set(extra_files DoxygenLayout.xml header.html footer.html extra.css spaces.svg)
|
|
|
|
set(header_paths
|
|
"${GLFW_SOURCE_DIR}/include/GLFW/glfw3.h"
|
|
"${GLFW_SOURCE_DIR}/include/GLFW/glfw3native.h")
|
|
|
|
# Format the source list into a Doxyfile INPUT value that Doxygen can parse
|
|
foreach(path IN LISTS header_paths)
|
|
string(APPEND GLFW_DOXYGEN_INPUT " \\\n\"${path}\"")
|
|
endforeach()
|
|
foreach(file IN LISTS source_files)
|
|
string(APPEND GLFW_DOXYGEN_INPUT " \\\n\"${CMAKE_CURRENT_SOURCE_DIR}/${file}\"")
|
|
endforeach()
|
|
|
|
configure_file(Doxyfile.in Doxyfile @ONLY)
|
|
|
|
add_custom_command(OUTPUT "html/index.html"
|
|
COMMAND "${DOXYGEN_EXECUTABLE}"
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
|
|
MAIN_DEPENDENCY Doxyfile
|
|
DEPENDS ${header_paths} ${source_files} ${extra_files}
|
|
COMMENT "Generating HTML documentation"
|
|
VERBATIM)
|
|
|
|
add_custom_target(docs ALL SOURCES "html/index.html")
|
|
set_target_properties(docs PROPERTIES FOLDER "GLFW3")
|
|
|