mirror of
https://github.com/open-goal/jak-project
synced 2026-08-20 14:24:45 -04:00
Alexander J. Semenuk
5d5e35fb9b
## Problem Windows builds break with a current local toolchain (Scoop LLVM 22.1.8, CMake 4.4.0, VS 2026), in two independent ways: 1. The build stops at curl's deliberate guard: `#error "no non-blocking method was found/used/set"` in `third-party/curl/lib/nonblock.c`. 2. From the second configure onward, `cmake --build` re-runs CMake in an endless loop (observed 42 consecutive reconfigure cycles in a single build). Likely the same mechanism behind the "endlessly building" VS 2026 note in `docs/setup/dev/vs.md`. ## Root cause 1. `third-party/curl/CMake/CurlTests.c` passes `int *` to `ioctlsocket()`, whose third parameter is `u_long *`. Clang 22 promotes `-Wincompatible-pointer-types` to a hard error in C, so the `HAVE_IOCTLSOCKET_FIONBIO` try_compile silently fails and `curl_config.h` never defines it. Upstream CI does not see this because the windows-2022 runner image ships an older LLVM. GCC 14 promotes the same warning to a hard error, which is very likely the `CurlTests.c.obj` failure reported from MSYS2 in open-goal/jak-project#3551. Upstream curl hit the identical problem with GCC 14 and fixed the probe in curl 8.8.0 (curl/curl#13578). 2. The root CMakeLists copies the build tree's `compile_commands.json` into `<src>/build/` for clangd using `configure_file()`, which registers its input as a configure dependency. CMake rewrites `compile_commands.json` late in every generation, after `CTestTestfile.cmake` and `cmake_install.cmake` (outputs of the same Ninja regen rule), so once the dependency is registered the rule is deterministically dirty and every `ninja` invocation re-runs CMake. A pristine first configure is safe (the file does not exist yet, so the `if(EXISTS ...)` guard skips the copy), which is why the loop looks machine- or IDE-specific. ## Fix 1. Per review, re-vendor `third-party/curl` at the `curl-8_21_0` tag (previously `curl-8_3_0`), which carries the upstream probe fix plus two years of upstream development; `vendor.yaml` updated to match. Adjustments the version jump forced: - curl 8.15 removed the native macOS Secure Transport backend (`CURL_USE_SECTRANSP`), so macOS now builds curl against OpenSSL like Linux. The two macOS workflows install Homebrew `openssl@3` and export `OPENSSL_ROOT_DIR` (keg-only), and the macOS setup docs gained the same two lines. - `CURL_BROTLI` / `CURL_ZSTD` switched to AUTO-detection in curl 8.10; pinned OFF to keep the previous no-compression behavior and avoid silently linking whatever the CI images happen to have. - curl's new top-level `BUILD_EXAMPLES` cache option (default ON) leaked into discord-rpc's identically named option and broke configure at a nonexistent `examples/send-presence` directory; pinned OFF ahead of the third-party subdirectories. The diff is dominated by the mechanical tag-tree swap under `third-party/curl` (linguist-vendored, collapsed in review). The hand-written changes are `CMakeLists.txt`, the two macOS workflows, `docs/setup/system/macos.md`, and `vendor.yaml`. 2. Swap `configure_file()` for `file(COPY ...)`: the same clangd copy with no configure dependency registered. (`file(COPY_FILE ... ONLY_IF_DIFFERENT)` would be cleaner still but requires CMake 3.21, above the declared `cmake_minimum_required(VERSION 3.10)`.) ## Test plan - [x] Fresh `cmake --preset Release-windows-clang` (LLVM 22, no cache seeding) completes and logs `Enabled SSL backends: Schannel`; the FIONBIO probe passes without the previous `#error` - [x] Full Windows Release build from scratch in the branch worktree (all 1422 targets) - [x] goalc-test suite: 1509 passed, 0 failed - [x] Second consecutive configure with `compile_commands.json` present: the regen rule in `build.ninja` has no `compile_commands.json` input; `<src>/build/compile_commands.json` is still refreshed for clangd - [x] Repeated `ninja` invocations after a full build no longer re-run CMake - [x] macOS Intel and ARM CI green (first exercise of the OpenSSL backend switch) --- I work off a self-hosted forge, so this GitHub account is quiet; the configure logs and ninja dirty-node traces from the investigation are available if anyone wants the raw data. (AI-assisted)
87 lines
3.4 KiB
CMake
Vendored
Generated
87 lines
3.4 KiB
CMake
Vendored
Generated
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# File containing various utilities
|
|
|
|
# Return number of arguments that evaluate to true
|
|
function(curl_count_true _output_count_var)
|
|
set(_list_len 0)
|
|
foreach(_option_var IN LISTS ARGN)
|
|
if(${_option_var})
|
|
math(EXPR _list_len "${_list_len} + 1")
|
|
endif()
|
|
endforeach()
|
|
set(${_output_count_var} ${_list_len} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
# Dump all defined variables with their values
|
|
function(curl_dumpvars)
|
|
message("::group::CMake Variable Dump")
|
|
get_cmake_property(_vars VARIABLES)
|
|
foreach(_var IN ITEMS ${_vars})
|
|
get_property(_var_type CACHE ${_var} PROPERTY TYPE)
|
|
get_property(_var_advanced CACHE ${_var} PROPERTY ADVANCED)
|
|
if(_var_type)
|
|
set(_var_type ":${_var_type}")
|
|
endif()
|
|
if(_var_advanced)
|
|
set(_var_advanced " [adv]")
|
|
endif()
|
|
message("${_var}${_var_type}${_var_advanced} = '${${_var}}'")
|
|
endforeach()
|
|
message("::endgroup::")
|
|
endfunction()
|
|
|
|
# Dump all target properties
|
|
function(curl_dumptargetprops _target)
|
|
if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.19 AND TARGET "${_target}")
|
|
execute_process(COMMAND "${CMAKE_COMMAND}" "--help-property-list" OUTPUT_VARIABLE _cmake_property_list)
|
|
string(REPLACE "\n" ";" _cmake_property_list "${_cmake_property_list}")
|
|
list(REMOVE_DUPLICATES _cmake_property_list)
|
|
list(REMOVE_ITEM _cmake_property_list "")
|
|
list(APPEND _cmake_property_list "INTERFACE_LIBCURL_PC_MODULES")
|
|
get_target_property(_target_imported ${_target} IMPORTED)
|
|
if(NOT _target_imported)
|
|
list(REMOVE_ITEM _cmake_property_list "LOCATION" "LOCATION_<CONFIG>" "MACOSX_PACKAGE_LOCATION" "VS_DEPLOYMENT_LOCATION")
|
|
endif()
|
|
foreach(_prop IN LISTS _cmake_property_list)
|
|
if(_prop MATCHES "<CONFIG>")
|
|
foreach(_config IN ITEMS "DEBUG" "RELEASE" "MINSIZEREL" "RELWITHDEBINFO")
|
|
string(REPLACE "<CONFIG>" "${_config}" _propconfig "${_prop}")
|
|
get_property(_is_set TARGET "${_target}" PROPERTY "${_propconfig}" SET)
|
|
if(_is_set)
|
|
get_target_property(_val "${_target}" "${_propconfig}")
|
|
message("${_target}.${_propconfig} = '${_val}'")
|
|
endif()
|
|
endforeach()
|
|
else()
|
|
get_property(_is_set TARGET "${_target}" PROPERTY "${_prop}" SET)
|
|
if(_is_set)
|
|
get_target_property(_val "${_target}" "${_prop}")
|
|
message("${_target}.${_prop} = '${_val}'")
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
endif()
|
|
endfunction()
|