mirror of
https://github.com/open-goal/jak-project
synced 2026-05-28 00:16:20 -04:00
Tyler Wilding
1f6438e517
This PR updates to SDL3, and with it, adds a handful of new features. Everything seems to work but I'm going to look over the code once last time before merging, some of the API changes are hard to spot. Fixes #2773 ### Pressure sensitivity support for DS3 Controllers SDL3 adds pressure sensitivity support for DS3 controllers on windows. I have not tested on linux. The option is disabled by default. On windows you will need https://docs.nefarius.at/projects/DsHidMini/ and to be using SXS mode. ### DualSense and Xbox One Trigger Effects If enabled, Jak 2 will have certain trigger effects. They are: - xbox1: - small vibrate when collecting dark eco - big vibrate when changing to dark jak - vibrate when shooting gun, proportional to gun type - ps5: - resistance when changing to dark jak - different gun shooting effects - red (resistance) - yellow (weapon trigger) - blue (vibrates) - purple (less resistance) > **Gun Shooting effects are only enabled if the new "Swap R1 and R2" option is enabled** There are more effects that could be used in `dualsense_effects.cpp`, but I only exposed the ones I needed to OpenGOAL. If a modder wants to use some of the others and wires them up end-to-end, please consider contributing that upstream. ### New ImGUI Menu Added new imgui options for selecting the active controller, for those people that struggle to select the initial controller.  ### Testing The highlights of what I tested successfully: - display - [x] all mode switch permutations - [x] launch with all modes saved - [x] switch monitors / unplug monitor that was active, how does it handle it - [x] load with alternate monitor saved and all modes - [x] allowing hidpi doesnt break macos - controls - [x] keyboard and mouse still work - [x] pressure sensitivity on linux
75 lines
2.3 KiB
CMake
Vendored
Generated
75 lines
2.3 KiB
CMake
Vendored
Generated
#[=======================================================================[
|
|
|
|
This CMake script is meant to be used in CMake script mode (cmake -P).
|
|
It wraps commands that communicate with an actual Android device.
|
|
Because
|
|
|
|
#]=======================================================================]
|
|
|
|
cmake_minimum_required(VERSION 3.16...3.28)
|
|
|
|
if(NOT CMAKE_SCRIPT_MODE_FILE)
|
|
message(FATAL_ERROR "This file can only be used in CMake script mode")
|
|
endif()
|
|
if(NOT ADB)
|
|
set(ADB "adb")
|
|
endif()
|
|
|
|
if(NOT ACTION)
|
|
message(FATAL_ERROR "Missing ACTION argument")
|
|
endif()
|
|
|
|
if(ACTION STREQUAL "uninstall")
|
|
# The uninstall action attempts to uninstall all packages. All failures are ignored.
|
|
foreach(package IN LISTS PACKAGES)
|
|
message("Uninstalling ${package} ...")
|
|
execute_process(
|
|
COMMAND ${ADB} uninstall ${package}
|
|
RESULT_VARIABLE res
|
|
)
|
|
message("... result=${res}")
|
|
endforeach()
|
|
elseif(ACTION STREQUAL "install")
|
|
# The install actions attempts to install APK's to an Android device using adb. Failures are ignored.
|
|
set(failed_apks "")
|
|
foreach(apk IN LISTS APKS)
|
|
message("Installing ${apk} ...")
|
|
execute_process(
|
|
COMMAND ${ADB} install -d -r --streaming ${apk}
|
|
RESULT_VARIABLE res
|
|
)
|
|
message("... result=${res}")
|
|
if(NOT res EQUAL 0)
|
|
list(APPEND failed_apks ${apk})
|
|
endif()
|
|
endforeach()
|
|
if(failed_apks)
|
|
message(FATAL_ERROR "Failed to install ${failed_apks}")
|
|
endif()
|
|
elseif(ACTION STREQUAL "build-install-run")
|
|
if(NOT EXECUTABLES)
|
|
message(FATAL_ERROR "Missing EXECUTABLES (don't know what executables to build/install and start")
|
|
endif()
|
|
if(NOT BUILD_FOLDER)
|
|
message(FATAL_ERROR "Missing BUILD_FOLDER (don't know where to build the APK's")
|
|
endif()
|
|
set(install_targets "")
|
|
foreach(executable IN LISTS EXECUTABLES)
|
|
list(APPEND install_targets "install-${executable}")
|
|
endforeach()
|
|
execute_process(
|
|
COMMAND ${CMAKE_COMMAND} --build "${BUILD_FOLDER}" --target ${install_targets}
|
|
RESULT_VARIABLE res
|
|
)
|
|
if(NOT res EQUAL 0)
|
|
message(FATAL_ERROR "Failed to install APK(s) for ${EXECUTABLES}")
|
|
endif()
|
|
list(GET EXECUTABLES 0 start_executable)
|
|
execute_process(
|
|
COMMAND ${CMAKE_COMMAND} --build "${BUILD_FOLDER}" --target start-${start_executable}
|
|
RESULT_VARIABLE res
|
|
)
|
|
else()
|
|
message(FATAL_ERROR "Unknown ACTION=${ACTION}")
|
|
endif()
|